Draw rotate (SOLVED)

[NoFontNL]

Hello, I want to draw 2 sprites above one another and draw them rotated.


Image angle only changes the object's sprite rotation.

And when using draw_sprite_ext, the sprites only get rotated around their own center point,
which results into this:


Any idea how to rotate them both around one specified center point, while not having to change the sprites' center point?

 

[YoSniper]

Define the center point, then the offsets. The rest is trig.

var x_offset_1, y_offset_1, x_offset_2, y_offset_2;

x_offset_1 = <sprite1 initial x offset> * dcos(angle) + <sprite1 initial y offset> * dsin(angle);
y_offset_1 = <sprite1 initial y offset> * dcos(angle) - <sprite1 initial x offset> * dsin(angle);
x_offset_2 = <sprite2 initial x offset> * dcos(angle) + <sprite2 initial y offset> * dsin(angle);
y_offset_2 = <sprite2 initial y offset> * dcos(angle) - <sprite2 initial x offset> * dsin(angle);

draw_sprite_ext(sprite1, index1, center_x + x_offset_1, center_y + y_offset_1, xscale, yscale, angle, c_white, 1);
draw_sprite_ext(sprite2, index2, center_x + x_offset_2, center_y + y_offset_2, xscale, yscale, angle, c_white, 1);

 

[NoFontNL]

/// draw_sprites_angle(cx,cy,angle,si_1,ii_1,xo_1,yo_1,si_2, ii_2, xo_2, yo_2 ...)
// cx: Center X : real
// cy: Center Y : real
// angle: angle : real
// si_n: Sprite Index : real
// ii_n: Image Index : real
// xo_n: x offset : real
// yo_n: y offset : real
// Example: draw_sprites_angle(x,y,90,sp_tile1,0,0,64,sp_tile2,0,0,128,sp_tile3,0,0,192);

var center_x = argument0;
var center_y = argument1;
var angle = argument2;
var si, ii, x_offset, y_offset;

for (var i = 3; i<argument_count; i+=2){
        if(i+3>=argument_count){
                continue;
        }
        si[i] = argument[i];
        ii[i] = argument[i+1];
     
        x_offset[i] = argument[i+2] * dcos(angle) + argument[i+3] * dsin(angle);
        y_offset[i] = argument[i+3] * dcos(angle) - argument[i+2] * dsin(angle);
       draw_sprite_ext(si[i], ii[i], center_x + x_offset[i], center_y + y_offset[i], xscale, yscale, angle, draw_get_color(), draw_get_alpha());
}

Tried making a script out of this, would this work?
And another question. Does this work with different center points of the sprites themselves?

 

[YoSniper]

Looks good at first glance. And yes, a script would help in such a case.

And yes, this should work fine with sprites having different origins. It's just the x and y offsets that need to be accounted for.

 

[NoFontNL]

Still having trouble. Just added the script, ran it from a test object. Got this:

 

[chamaeleon]

Still having trouble. Just added the script, ran it from a test object. Got this:
View attachment 25443

GMS (current version 2 anyway), does not like mixing the use of argument0, argument1, etc., with argument[0], argument[1], and so on. Pick one style or the other. In this case, presumably the array version is better given a loop over the set provided arguments.

 

[NoFontNL]

Above script isn't working right, I made some minor changes that broke it.
Here is the full working script thanks to all people above that helped me especially YoSniper for the base with those mathematical expressions stuff and chamaeleon to finish it. (didn't know about the difference between argument0 and argument[0])

/// draw_sprites_angle(cx,cy,angle,si_1,ii_1,xo_1,yo_1,si_2, ii_2, xo_2, yo_2 ...)
// cx: Center X : real
// cy: Center Y : real
// angle: angle : real
// si_n: Sprite Index : real
// ii_n: Image Index : real
// xo_n: x offset : real
// yo_n: y offset : real
// Example: draw_sprites_angle(x,y,90,sp_tile1,0,0,64,sp_tile2,0,0,128,sp_tile3,0,0,192);
// Thread: https://forum.yoyogames.com/index.php?threads/draw-rotate.64780/

var center_x = argument[0];
var center_y = argument[1];
var angle = argument[2];
var si, ii, x_offset, y_offset;

for (var i = 3; i<argument_count; i+=4){
        if(i+3>=argument_count){
                continue;
        }
        si[i] = argument[i];
        ii[i] = argument[i+1];
     
        x_offset[i] = argument[i+2] * dcos(angle) + argument[i+3] * dsin(angle);
        y_offset[i] = argument[i+3] * dcos(angle) - argument[i+2] * dsin(angle);
       draw_sprite_ext(si[i], ii[i], center_x + x_offset[i], center_y + y_offset[i], image_xscale, image_yscale, angle, c_white, draw_get_alpha());
}